#version 120
uniform int resolution_horizontal = 100;
uniform sampler2D bgl_RenderTexture;
const vec2 LeftLensCenter = vec2(0.287994117, 0.5);
const vec2 RightLensCenter = vec2(0.712005913, 0.5);
const vec2 LeftScreenCenter = vec2(0.25, 0.5);
const vec2 RightScreenCenter = vec2(0.75, 0.5);
const vec2 Scale = vec2(0.145806134, 0.233289823);
const vec2 ScaleIn = vec2(4.0, 2.5);
const vec4 HmdWarpParam = vec4(1.0, 0.22, 0.24, 0.0);

// Scales input texture coordinates for distortion.
vec2 HmdWarp(vec2 in01, vec2 LensCenter)
{
	vec2 theta = (in01 - LensCenter) * ScaleIn; // Scales to [-1, 1]
	float rSq = theta.x * theta.x + theta.y * theta.y;
	vec2 rvector = theta * (HmdWarpParam.x + HmdWarpParam.y * rSq +
		HmdWarpParam.z * rSq * rSq + 
		HmdWarpParam.w * rSq * rSq * rSq);
	return LensCenter + Scale * rvector;
}

void main()
{
	int oculus_half_width = int(resolution_horizontal/2);
	// The following two variables need to be set per eye
	vec2 LensCenter = gl_FragCoord.x < oculus_half_width ? LeftLensCenter : RightLensCenter;
	vec2 ScreenCenter = gl_FragCoord.x < oculus_half_width ? LeftScreenCenter : RightScreenCenter;

	vec2 oTexCoord = gl_TexCoord[0].xy;

	vec2 tc = HmdWarp(oTexCoord, LensCenter);
	if (any(bvec2(clamp(tc,ScreenCenter-vec2(0.25,0.5), ScreenCenter+vec2(0.25,0.5)) - tc)))
	{
		gl_FragColor = vec4(vec3(0.0), 1.0);
		return;
	}
	gl_FragColor = texture2D(bgl_RenderTexture, tc);
}